如何在inputbox中輸入以‘*’形式顯示的密碼?


請寫得詳細些,最好以代碼形式說明。我上網查了一些,雖然按照帖子上面的說法改了,可仍然不好使。拜托大家了!

14 个解决方案

#1




function InputQuery(const ACaption, APrompt: string;
  var Value: string): Boolean;
var
  Form: TForm;
  Prompt: TLabel;
  Edit: TEdit;//改成 MaskEdit1: TMaskEdit;

  DialogUnits: TPoint;
  ButtonTop, ButtonWidth, ButtonHeight: Integer;
begin
  Result := False;
  Form := TForm.Create(Application);
  with Form do
    try
      Canvas.Font := Font;
      DialogUnits := GetAveCharSize(Canvas);
      BorderStyle := bsDialog;
      Caption := ACaption;
      ClientWidth := MulDiv(180, DialogUnits.X, 4);
      Position := poScreenCenter;
      Prompt := TLabel.Create(Form);
      with Prompt do
      begin
        Parent := Form;
        Caption := APrompt;
        Left := MulDiv(8, DialogUnits.X, 4);
        Top := MulDiv(8, DialogUnits.Y, 8);
        Constraints.MaxWidth := MulDiv(164, DialogUnits.X, 4);
        WordWrap := True;
      end;
      Edit := TEdit.Create(Form);//改成 MaskEdit1
      with Edit do  ///改成 MaskEdit1
      begin
        Parent := Form;
        Left := Prompt.Left;
        Top := Prompt.Top + Prompt.Height + 5;
        Width := MulDiv(164, DialogUnits.X, 4);
        MaxLength := 255;
        Text := Value;
        SelectAll;
      end;
      ButtonTop := Edit.Top + Edit.Height + 15;
      ButtonWidth := MulDiv(50, DialogUnits.X, 4);
      ButtonHeight := MulDiv(14, DialogUnits.Y, 8);
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := SMsgDlgOK;
        ModalResult := mrOk;
        Default := True;
        SetBounds(MulDiv(38, DialogUnits.X, 4), ButtonTop, ButtonWidth,
          ButtonHeight);
      end;
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := SMsgDlgCancel;
        ModalResult := mrCancel;
        Cancel := True;
        SetBounds(MulDiv(92, DialogUnits.X, 4), Edit.Top + Edit.Height + 15,
          ButtonWidth, ButtonHeight);
        Form.ClientHeight := Top + Height + 13;          
      end;
      if ShowModal = mrOk then
      begin
        Value := Edit.Text;
        Result := True;
      end;
    finally
      Form.Free;
    end;
end;

function InputBox(const ACaption, APrompt, ADefault: string): string;
begin
  Result := ADefault;
  InputQuery(ACaption, APrompt, Result);
end;

上面是INPUTBOX在delphi中的定義,你自己改一下,將edit->masktedit就可以了

#2


將Edit的屬性passwordchar由#0改為*即可

#3


引用 2 樓 yangkunjie 的回復:
將Edit的屬性passwordchar由#0改為*即可

我說錯了,同意樓上說法

#4


方法1:將InputBox中的InputQuery修改一下

  with Edit do
  begin
    Parent := Form;
    Left := Prompt.Left;
    Top := Prompt.Top + Prompt.Height + 5;
    Width := MulDiv(164, DialogUnits.X, 4);
    MaxLength := 255;
    Text := Value;
    PasswordChar:='*'//加上此句
    SelectAll;
  end;

方法2:通過發送消息來修改
1.獲取InputBox中的Edit框句柄
2.SendMessage(Handle, EM_SETPASSWORDCHAR, Ord('*'), 0);

#5


為什么非要inputbox呢,直接自己畫一個窗口不行嗎?

#6


為什么非要inputbox呢,直接自己畫一個窗口不行嗎?

#7


引用 2 樓 yangkunjie 的回復:
將Edit的屬性passwordchar由#0改為*即可

#8


PasswordChar:='*';

#9


引用 4 樓 liangpei2008 的回復:
方法1:將InputBox中的InputQuery修改一下 

......

方法2:通過發送消息來修改 
1.獲取InputBox中的Edit框句柄 
2.SendM…


InputBox是ShowModal出來的,沒有結束對話框之前,下面的代碼是不會被執行的。所以,第二種方法是不可行的。

#10


感謝大家的熱情回答。
“PasswordChar:='*'//加上此句 ”這句加上了,可輸入的時候還是沒變成‘*’,why?自己畫一個窗口的方法,我也知道。是一個朋友非要這么做,我只好來求大家幫助了!

#11


uses
  Consts;
function GetAveCharSize(Canvas: TCanvas): TPoint;
var
  I: Integer;
  Buffer: array[0..51] of Char;
begin
  for I := 0 to 25 do Buffer[I] := Chr(I + Ord('A'));
  for I := 0 to 25 do Buffer[I + 26] := Chr(I + Ord('a'));
  GetTextExtentPoint(Canvas.Handle, Buffer, 52, TSize(Result));
  Result.X := Result.X div 52;
end;
function InputQueryEx(const ACaption, APrompt: string;
  var Value: string; APassWordChar: char = #0): Boolean;
var
  Form: TForm;
  Prompt: TLabel;
  Edit: TEdit;
  DialogUnits: TPoint;
  ButtonTop, ButtonWidth, ButtonHeight: Integer;
begin
  Result := False;
  Form := TForm.Create(Application);
  with Form do
    try
      Canvas.Font := Font;
      DialogUnits := GetAveCharSize(Canvas);
      BorderStyle := bsDialog;
      Caption := ACaption;
      ClientWidth := MulDiv(180, DialogUnits.X, 4);
      Position := poScreenCenter;
      Prompt := TLabel.Create(Form);
      with Prompt do
      begin
        Parent := Form;
        Caption := APrompt;
        Left := MulDiv(8, DialogUnits.X, 4);
        Top := MulDiv(8, DialogUnits.Y, 8);
        Constraints.MaxWidth := MulDiv(164, DialogUnits.X, 4);
        WordWrap := True;
      end;
      Edit := TEdit.Create(Form);
      with Edit do
      begin
        passwordchar := APassWordChar;
        Parent := Form;
        Left := Prompt.Left;
        Top := Prompt.Top + Prompt.Height + 5;
        Width := MulDiv(164, DialogUnits.X, 4);
        MaxLength := 255;
        Text := Value;
        SelectAll;
      end;
      ButtonTop := Edit.Top + Edit.Height + 15;
      ButtonWidth := MulDiv(50, DialogUnits.X, 4);
      ButtonHeight := MulDiv(14, DialogUnits.Y, 8);
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := SMsgDlgOK;
        ModalResult := mrOk;
        Default := True;
        SetBounds(MulDiv(38, DialogUnits.X, 4), ButtonTop, ButtonWidth,
          ButtonHeight);
      end;
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := SMsgDlgCancel;
        ModalResult := mrCancel;
        Cancel := True;
        SetBounds(MulDiv(92, DialogUnits.X, 4), Edit.Top + Edit.Height + 15,
          ButtonWidth, ButtonHeight);
        Form.ClientHeight := Top + Height + 13;          
      end;
      if ShowModal = mrOk then
      begin
        Value := Edit.Text;
        Result := True;
      end;
    finally
      Form.Free;
    end;
end;

function InputBoxEx(const ACaption, APrompt, ADefault: string;PassWordChar: char = #0): string;
begin
  Result := ADefault;
  InputQueryEx(ACaption, APrompt, Result, PassWordChar);
end;

#12


InputBoxEx('測試密碼輸入','請輸入密碼:','password','*');

#13


感覺自已做個form省事點。

#14


你們都很厲害

注意!

本站转载的文章为个人学习借鉴使用,本站对版权不负任何法律责任。如果侵犯了您的隐私权益,请联系我们删除。



 
粤ICP备14056181号  © 2014-2021 ITdaan.com